text.setBorderStyle(SHADOW, 0xFF000000, 8, 0);

package states;

import flixel.FlxG;
import flixel.text.FlxText;

class TextShadowTestState extends flixel.FlxState
{
	var text:FlxText;
	var showBorder = true;
	var shadowSize = 16;
	var shadowQuality = 0;
	
	var instructions:FlxText;
	
	override public function create()
	{
		super.create();
		bgColor = 0xFFff0000;
		
		text = new FlxText();
		text.text = "FlxText shadow clipping test lol";
		text.size = 32;
		text.screenCenter();
		// text.borderStyle = SHADOW;
		// text.shadowOffset.set(8, 8);
		applyShadow();
		add(text);
		
		// debug watch
		FlxG.watch.addFunction("bmd", function ()
		{
			final bmp = text.graphic.bitmap;
			return '( w: ${bmp.width} | h: ${bmp.height} )';
		});
		FlxG.watch.addFunction("shd.offset", ()->text.shadowOffset);
		FlxG.watch.addFunction("shd.size", ()->text.borderSize);
		FlxG.watch.addFunction("shd.quality", ()->text.borderQuality);
		FlxG.watch.addFunction("shd.style", ()->text.borderStyle.getName());
		FlxG.log.notice("LEFT/RIGHT: change shadowOffset");
		FlxG.log.notice("SPACE: reset shadowOffset");
		FlxG.log.notice("UP/DOWN: change borderSize");
		FlxG.log.notice("SHIFT + ^ v: change borderQuality");
		FlxG.log.notice("CLICK: toggle border");
		FlxG.debugger.visible = true;
	}
	
	function applyShadow()
	{
		if (showBorder)
			text.setBorderStyle(SHADOW, 0xFF000000, shadowSize, shadowQuality);
		else
			text.setBorderStyle(NONE);
		
		@:privateAccess text._regen = true;
		@:privateAccess text.regenGraphic();
		FlxG.bitmapLog.clear();
		FlxG.bitmapLog.add(text.graphic.bitmap);
	}

	override public function update(elapsed:Float)
	{
		super.update(elapsed);
		
		var redraw = false;
		
		if (FlxG.keys.anyJustPressed([SPACE, RIGHT, LEFT]))
		{
			if (FlxG.keys.justPressed.SPACE) text.shadowOffset.set(1, 1);
			if (FlxG.keys.justPressed.RIGHT) text.shadowOffset.add(1, 1);
			if (FlxG.keys.justPressed.LEFT) text.shadowOffset.add(-1, -1);
			
			redraw = true;
		}
		
		if (FlxG.keys.anyJustPressed([UP, DOWN]))
		{
			if (FlxG.keys.pressed.SHIFT)
			{
				if (FlxG.keys.justPressed.UP && shadowQuality < 2) shadowQuality++;
				if (FlxG.keys.justPressed.DOWN && shadowQuality > 0) shadowQuality--;
			}
			else
			{
				if (FlxG.keys.justPressed.UP) shadowSize++;
				if (FlxG.keys.justPressed.DOWN) shadowSize--;
			}
			
			redraw = true;
		}
		
		if (FlxG.mouse.justPressed)
		{
			showBorder = !showBorder;
			redraw = true;
		}
		
		if (redraw)
			applyShadow();
	}
}